Nullsoft Scriptable Install System | NSIS - [46] :: Программы :: Компьютерный форум Ru.Board

Цитата:

Интересует так же как в этих страницах сделать так, чтобы был разный текст именно в заголовках страниц? Допустим мне вот необходимо сделать две страницы с разными заголовками, на одной информация о программе, на другой - авторы программы.

Вот для одной страницы (из примера).

${ReadmeLanguage} "${LANG_ENGLISH}" \
"Информация" \
"Пожалуйста, ознакомьтесь с нижеследующей информацией." \
"Информация о программе:" \
"$\n Нажмите кнопку 'Далее' для продолжения."

А как для двух страниц-то прописать?

На этот вопрос как и на предыдущие ранее, самый простой ответ один, продублировать то что было создано для дополнительной страницы - README.

Часть первая:
Сделать это можно примерно так, для файла *.nsh

;--------------------------------
# MUI_EXTRAPAGES.nsh
# By Red Wine Jan 2007

!verbose push
!verbose 3

!ifndef _MUI_EXTRAPAGES_NSH
!define _MUI_EXTRAPAGES_NSH

!ifmacrondef MUI_EXTRAPAGE_AUTHOR & MUI_PAGE_AUTHOR & MUI_UNPAGE_AUTHOR & AuthorLangStrings

!macro MUI_EXTRAPAGE_AUTHOR UN AuthorFile
!verbose push
!verbose 3
!define MUI_PAGE_HEADER_TEXT "$(${UN}AuthorHeader)"
!define MUI_PAGE_HEADER_SUBTEXT "$(${UN}AuthorSubHeader)"
!define MUI_LICENSEPAGE_TEXT_TOP "$(${UN}AuthorTextTop)"
!define MUI_LICENSEPAGE_TEXT_BOTTOM "$(${UN}AuthorTextBottom)"
!define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
!insertmacro MUI_${UN}PAGE_LICENSE "${AuthorFile}"
!verbose pop
!macroend

!define AuthorRun "!insertmacro MUI_EXTRAPAGE_AUTHOR"

!macro MUI_PAGE_AUTHOR AuthorFile
!verbose push
!verbose 3
${AuthorRun} "" "${AuthorFile}"
!verbose pop
!macroend

!macro MUI_UNPAGE_AUTHOR AuthorFile
!verbose push
!verbose 3
${AuthorRun} "UN" "${AuthorFile}"
!verbose pop
!macroend

!macro AuthorLangStrings UN MUI_LANG AuthorHeader AuthorSubHeader AuthorTextTop AuthorTextBottom
!verbose push
!verbose 3
LangString ${UN}AuthorHeader ${MUI_LANG} "${AuthorHeader}"
LangString ${UN}AuthorSubHeader ${MUI_LANG} "${AuthorSubHeader}"
LangString ${UN}AuthorTextTop ${MUI_LANG} "${AuthorTextTop}"
LangString ${UN}AuthorTextBottom ${MUI_LANG} "${AuthorTextBottom}"
!verbose pop
!macroend

!define AuthorLanguage `!insertmacro AuthorLangStrings ""`

!define Un.AuthorLanguage `!insertmacro AuthorLangStrings "UN"`

!endif
!endif

!verbose pop

Часть вторая:
Немного изменений для файла скрипта *.nsi, то что необходимо указано в примере ниже:

;--------------------------------
;Installer Pages
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"

;Add the install read me page
!insertmacro MUI_PAGE_README "${NSISDIR}\Docs\Modern UI\Changelog.txt"

;Add the install authors page
!insertmacro MUI_PAGE_AUTHOR "${NSISDIR}\Docs\Modern UI\Authors.txt"

!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

;--------------------------------
;Uninstaller Pages
!insertmacro MUI_UNPAGE_WELCOME

;Add the uninstall license page
!insertmacro MUI_UNPAGE_LICENSE '${NSISDIR}\License.txt'
;Add the uninstall read me page
!insertmacro MUI_UNPAGE_README '${NSISDIR}\Changelog.txt'
;Add the uninstall authors page
!insertmacro MUI_UNPAGE_AUTHOR '${NSISDIR}\Authors.txt'

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

;--------------------------------
;Languages
;Add 1st language
!insertmacro MUI_LANGUAGE "English"

;Set up install lang strings for 1st lang
${AuthorLanguage} "${LANG_ENGLISH}" \
"Authors" \
"Please review the following important information." \
"About $(^name):" \
"$\n Click on scrollbar arrows or press Page Down to review the entire text."

;Set up uninstall lang strings for 1st lang
${Un.AuthorLanguage} "${LANG_ENGLISH}" \
"Authors" \
"Please review the following important Uninstall information." \
"About $(^name) Uninstall:" \
"$\n Click on scrollbar arrows or press Page Down to review the entire text."

;Add 2nd language
!insertmacro MUI_LANGUAGE "Greek"

;set up install lang strings for second lang
${AuthorLanguage} "${LANG_GREEK}" \
"Authors" \
"Please review the following important information." \
"About $(^name):" \
"$\n Click on scrollbar arrows or press Page Down to review the entire text."

;set up uninstall lang strings for second lang
${Un.AuthorLanguage} "${LANG_GREEK}" \
"Authors" \
"Please review the following important Uninstall information." \
"About $(^name) Uninstall:" \
"$\n Click on scrollbar arrows or press Page Down to review the entire text."

...

SectionEnd

Вот собственно и все, далее изменяй текст так как тебе будет нужно. Скрипт не тестировал и не проверял, но думаю он должен работать...

Удачи.

Модерирует : gyra, Maz
Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117