unreal666
Gold Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: @ECHO OFF
ECHO === Регистрация расширений Opera ===
SETLOCAL EnableExtensions EnableDelayedExpansion
REM OperaPath - это полный путь к opera.exe. Если его не задавать вручную и если opera уже хоть раз запускалась, то эта инфа взята из реестра
SET "OperaPath="
SET HTMLPages=htm html xht xhtm xhtml
SET MHTMLPages=mht mhtml
SET AllHTMLPages=%HTMLPages% %MHTMLPages%
SET Protocols=FTP HTTP HTTPS
IF /i "%PROCESSOR_ARCHITECTURE%"=="AMD64" (SET "Wow6432Node=\Wow6432Node\") ELSE (SET "Wow6432Node=\")
IF NOT DEFINED OperaPath FOR /f "tokens=4,*" %%a IN ('REG QUERY "HKCU\Software\Opera Software" /v "Last CommandLine v2" ^| FIND /i "REG_SZ"') DO SET OperaPath=%%b
IF NOT DEFINED OperaPath FOR /f "tokens=3,*" %%a IN ('REG QUERY "HKCU\Software\Opera Software" /v "Last CommandLine" ^| FIND /i "REG_SZ"') DO SET OperaPath=%%b
IF NOT DEFINED OperaPath SET /P OperaPath=Укажите полный путь к opera.exe
IF DEFINED OperaPath (
SET OperaPath=!OperaPath:"=!
SET OperaPath=!OperaPath!///
SET OperaPath=!OperaPath: ///=!
SET OperaPath=!OperaPath:///=!
REM Удаление разделов реестра, связанных с Opera.*
FOR %%a IN (!Protocols!) DO (
reg delete HKCR\Opera.%%a /f >nul
)
reg delete HKCR\Opera.HTML /f >nul
reg delete HKCR\Opera.MHTML /f >nul
reg delete HKCR\Opera.Image /f >nul
reg delete HKCR\Opera.Widget /f >nul
REM ----------------------------------------
reg add HKLM\SOFTWARE\RegisteredApplications /v "Opera" /d "Software\Opera\Capabilities" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities /v "ApplicationName" /d "Opera" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities /v "ApplicationDescription" /d "Opera. Один из лучших Интернет-браузеров" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".htm" /d "Opera.HTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".html" /d "Opera.HTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".xht" /d "Opera.HTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".xhtm" /d "Opera.HTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".xhtml" /d "Opera.HTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".mht" /d "Opera.MHTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".mhtml" /d "Opera.MHTML" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".url" /d "Opera.URL" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\FileAssociations /v ".wgt" /d "Opera.Widget" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\UrlAssociations /v "ftp" /d "Opera.FTP" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\UrlAssociations /v "http" /d "Opera.HTTP" /f >nul
reg add HKLM\SOFTWARE!Wow6432Node!Opera\Capabilities\UrlAssociations /v "https" /d "Opera.HTTPS" /f >nul
REM ----------------------------------------
reg add HKCR\Applications\opera.exe\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
reg add HKCR\Applications\opera.exe\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Applications\opera.exe\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Applications\opera.exe\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
REM ----------------------------------------
FOR %%a IN (!Protocols!) DO (
reg add HKCR\Opera.%%a /ve /d "URL:Протокол %%a" /f >nul
reg add HKCR\Opera.%%a\DefaultIcon /ve /d "%%SystemRoot%%\system32\url.dll,0" /f >nul
reg add HKCR\Opera.%%a\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
reg add HKCR\Opera.%%a\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Opera.%%a\shell\open\ddeexec /v "NoActivateHandler" /d "" /f >nul
reg add HKCR\Opera.%%a\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Opera.%%a\shell\open\ddeexec\IfExec /ve /d "" /f >nul
reg add HKCR\Opera.%%a\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
)
reg add HKCR\Opera.HTML /ve /d "HTML Document" /f >nul
reg add HKCR\Opera.HTML /v "FriendlyTypeName" /d "Opera Web Document" /f >nul
reg add HKCR\Opera.HTML\DefaultIcon /ve /d "!OperaPath!,1" /f >nul
reg add HKCR\Opera.HTML\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
reg add HKCR\Opera.HTML\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Opera.HTML\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Opera.HTML\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
reg add HKCR\Opera.MHTML /ve /d "MHTML Document" /f >nul
reg add HKCR\Opera.MHTML /v "FriendlyTypeName" /d "Opera Web Document" /f >nul
reg add HKCR\Opera.MHTML\DefaultIcon /ve /d "!OperaPath!,1" /f >nul
reg add HKCR\Opera.MHTML\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
reg add HKCR\Opera.MHTML\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Opera.MHTML\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Opera.MHTML\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
reg add HKCR\Opera.Image /ve /d "Image" /f >nul
reg add HKCR\Opera.Image /v "FriendlyTypeName" /d "Opera Image" /f >nul
reg add HKCR\Opera.Image\DefaultIcon /ve /d "!OperaPath!,1" /f >nul
reg add HKCR\Opera.Image\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
reg add HKCR\Opera.Image\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Opera.Image\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Opera.Image\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
reg add HKCR\Opera.Widget /ve /d "Opera Widget" /f >nul
reg add HKCR\Opera.Widget /v "FriendlyTypeName" /d "Opera Widget" /f >nul
reg add HKCR\Opera.Widget\DefaultIcon /ve /d "!OperaPath!,4" /f >nul
reg add HKCR\Opera.Widget\shell\open\command /ve /d "\"!OperaPath!\" -widget \"%%1\"" /f >nul
reg add HKCR\Opera.Widget\shell\open\ddeexec /ve /d "\"%%1\"" /f >nul
reg add HKCR\Opera.Widget\shell\open\ddeexec\Application /ve /d "Opera" /f >nul
reg add HKCR\Opera.Widget\shell\open\ddeexec\Topic /ve /d "WWW_OpenURL" /f >nul
REM Запись инфы о расширениях и протоколах
FOR %%a IN (!Protocols!) DO (
reg add HKCU\Software\Classes\%%a\shell /ve /d "open" /f >nul
reg add HKCU\Software\Classes\%%a\shell\open\command /ve /d "\"!OperaPath!\" \"%%1\"" /f >nul
)
FOR %%a IN (!HTMLPages!) DO (
reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%a /f >nul
reg add HKCU\Software\Classes\.%%a /ve /d "Opera.HTML" /f >nul
reg add HKCU\Software\Classes\.%%a /v "Content Type" /d "text/html" /f >nul
reg add HKCU\Software\Classes\.%%a /v "PerceivedType" /d "text" /f >nul
)
FOR %%a IN (!MHTMLPages!) DO (
reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%a /f >nul
reg add HKCU\Software\Classes\.%%a /ve /d "Opera.MHTML" /f >nul
reg add HKCU\Software\Classes\.%%a /v "Content Type" /d "message/rfc822" /f >nul
)
reg add HKCU\Software\Classes\.wgt /ve /d "Opera.Widget" /f >nul
ECHO Регистрация завершена
) ELSE ECHO Путь к Opera не указан
: END
ENDLOCAL |
|
Всего записей: 6637 | Зарегистр. 14-02-2005 | Отправлено: 01:42 20-11-2011 | Исправлено: unreal666, 03:45 20-11-2011 |
|
