Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)

Модерирует : gyra, Maz

Widok (19-11-2007 12:08): лимит страниц. продолжаем здесь  Версия для печати • ПодписатьсяДобавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118

   

KLASS



Moderator
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Командная строка, батники\сценарии (bat, cmd)
Вопросы, задачи и их решения по работе с командной строкой, файлами, а также сопутствующие ссылки.

 
Важно: копируя батник через буфер обмена из форума не забывайте удалять пробелы в конце каждой строки, т.к. в некоторых случаях из-за этого программа будет работать неправильно!!!
 
Примечание: Большие куски кода заключайте в тэг [more]  
 
Смежные темы:
В помощь системному администратору » Автоматизация администрирования
Microsoft Windows » Задачи на bat-файлах 4
 
Полезные ссылки:
· Cmd. Описание от разработчиков
· Урок bat-аники (для начинающих)
· Набор GNU утилит для win32
· Пакет утилит для организации интерфейса в bat-файлах
· Использование ansi.sys
· cmdow — изменение параметров и видимости дос-окна
· blat — отправка почты из консоли
· Справка по командам в виде Html
· Команды RunDll32
· Quick Batch File Compiler - Позволяет превратить ваш батник в независимое приложение
· Пример - получение и обработка списка пользователей
 
 
Старая версия первого сообщения

Всего записей: 9732 | Зарегистр. 12-10-2001 | Отправлено: 04:28 24-09-2002 | Исправлено: Elroir, 19:35 11-09-2007
bredonosec



Platinum Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Если внутри что-то есть, то RD (по крайней мере, согласно досу 6,22) не удаляет, требует опустошения папки.
Чтоб удалить целиком - deltree [ключи, имена, трафаретные знаки]
//лень вспоминать синтаксис )

Всего записей: 16012 | Зарегистр. 13-02-2003 | Отправлено: 07:27 18-10-2005
KapralBel



Platinum Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
bredonosec
RD <Папка> /Q /S - Удаляет <Папка>, со всеми подпапками и файлами (/s)? и без вопросов (/q)

Всего записей: 11354 | Зарегистр. 16-02-2005 | Отправлено: 10:40 18-10-2005
bredonosec



Platinum Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
KapralBel
Значится, отличие новых версий ком.строки от доса.  
Раньше низзя было. Сверился по ману.

Всего записей: 16012 | Зарегистр. 13-02-2003 | Отправлено: 23:29 22-10-2005
KapralBel



Platinum Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
bredonosec
Дык вопрос стоял про возможности винды, начиная с 2000 (судя по наличию папок $NT...$ )

Всего записей: 11354 | Зарегистр. 16-02-2005 | Отправлено: 11:41 24-10-2005
Smitis



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
bredonosec

Цитата:
Чтоб удалить целиком - deltree [ключи, имена, трафаретные знаки]  
//лень вспоминать синтаксис  

 
deltree [/y] папка1[\] [папка2[\] ...]
Если путь заканчивать на \, то будет удалено содержимое папки, а сама она останется. Иначе папка будет удалена полностью.
 
deltree будет работать и под NT,2K,XP..., если её туда забросить (если кому нужна совместимоть батников для разных систем)

Всего записей: 2433 | Зарегистр. 09-02-2003 | Отправлено: 00:21 26-10-2005
HWG

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Подскажите как в батнике сделать: посчитать количество строк в файле и вывести это количество на экран? Можно конешно написать програмку на паскале например и проблемы не будет, но желательно обойтись без этого

Всего записей: 38 | Зарегистр. 27-10-2002 | Отправлено: 01:00 26-10-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
HWG
В батниках если юзать FOR, в конструкции типа:

Код:
@ECHO OFF
 
SET /A COUNT=0
FOR /F %%A IN (TEST.TXT) DO SET /A COUNT+=1
ECHO Lines in TEST.TXT - %COUNT%
 
PAUSE
- пустые строчки не считаются
Лучше VBScript.  How Can I Count the Number of Lines in a Text File?
 
Если не устроит, то уже есть уйма всякой консольной [censored] вроде Word Count (wc.com), lc.exe, numlines.exe, wc.exe из GNU utilities for Win32 В гугле набери "Count lines in file + batch" или похожее, еще штук двадцать таких найдешь. Или и правда свою напиши    
 
P.S. Сам пользуюсь wc.exe из GNU utils.  wc - стандартная юниксовская команда
 

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 02:44 26-10-2005 | Исправлено: igor_andreev, 02:57 26-10-2005
HWG

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
igor_andreev
Спасибо. Я делал похоже, но неправильно у меня вместо  
SET /A COUNT+=1  было SET /A COUNT=%%A+1, поэтому результатом всегда было 2
 

Всего записей: 38 | Зарегистр. 27-10-2002 | Отправлено: 23:08 26-10-2005
HWG

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Имеется файл с текстом вида

Цитата:
TEXT1 TEXT2 TEXT3
в результате работы батника к нему добавляются еще строки, необходимо удалить из всего файла TEXT1 (всегда одинаков) перед добавлением новой строки. Такое возможно средствами cmd файлов без дополнительных приблуд?

Всего записей: 38 | Зарегистр. 27-10-2002 | Отправлено: 09:49 02-11-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
 Такое возможно средствами cmd файлов без дополнительных приблуд?

В этом топике смотри вопрос scup на седьмой странице. Команда FOR /F
 
3Ы: Ктоб не поленился , и шапку в топике сделал, с howto?

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 10:20 02-11-2005 | Исправлено: igor_andreev, 10:28 02-11-2005
Da_Neil



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Есть CUE-файлы, в которых есть такие строки:
Код:
FILE "CDImage.ape" WAVE
.
Нужно извлечь из них имя файла и проверить его существование. Если разбирать задачу по частям, вроде всё понятно: и как строку egrep'ом извлечь, и как наличие проверить с помощью if exist. Неясно одно: как перенаправить вывод egrep'a в команду if.

Всего записей: 3420 | Зарегистр. 05-03-2002 | Отправлено: 23:43 06-11-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
как перенаправить вывод egrep'a в команду if.  

Может вывод egrep'a записать в файл? А в винде SET /P умеет брать значение переменной из файла.

Код:
 
@echo off
echo someword>file.tmp
set /p VAR=<file.tmp
del file.tmp
echo %VAR%
pause
 

Первой строчкой вместо "echo someword>file.tmp" - "egrep параметры>file.tmp". Ну и дальше иф ексист %VAR%...
 
Хотя я например обычно из FOR /F все что надо выковыриваю, но текста батника твоего не знаю, да и с синтаксисом egrep не знаком, побаиваюсь не то подсказать

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 00:12 07-11-2005 | Исправлено: igor_andreev, 00:17 07-11-2005
Da_Neil



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
igor_andreev
Нашёл обходное решение, но оно как-то очень криво и непредсказуемо работает..  
Вот текст скрипта:  

Код:
setlocal
FOR /F "usebackq delims=" %%f IN (`findstr /B "FILE " "%~1"`) DO (
SET cueline=%%f
echo %cueline%
set cuefile=%cueline:~6,-6%
echo %cuefile%
)
endlocal
pause

 
А вот результат исполнения:  

Код:
 
S:\>setlocal
 
S:\>FOR /F "usebackq delims=" %f IN (`findstr /B "FILE " "D:\Distro\Downloads\ed2k\Frame - Afo 4 (Ape) by ST\Frame - Afo 4.cue"`) DO (
SET cueline=%f  
 echo    
 set cuefile=~6,-6  
 echo  
)  
 
S:\>(
SET cueline=FILE "Frame - Afo 4.wv" WAVE
echo    
 set cuefile=~6,-6  
 echo  

)  
ECHO is on.
ECHO is on.

 
S:\>endlocal
 
S:\>pause
Press any key to continue . . .  
 

 
Как видно, в строке SET cueline.. переменной присваивается значение, а в следующих строках идёт обработка, но! процессор как будто сразу же "забывает" её значение! Причём, если убрать составной оператор (скобки), склероз как рукой снимает. Полтергейтс, одним словом..

Всего записей: 3420 | Зарегистр. 05-03-2002 | Отправлено: 20:38 07-11-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
Нашёл обходное решение

Это не обходное, это правильное, я сие и имел ввиду(из FOR /F выковыривать)
 
1. Если батнику передаешь параметр(в SendTo хочешь батник положить?), рекомендую писать не %~1, а %~s1 или %~fs1 или %~dpnxs1. Короткое имя файла *.cue то есть, винда все правильно передаст. И от лишних кавычек, и если в пути к файлу есть скобки, восклицательные знаки, апострофы и т.п. - от всего избавишься. А то дествительно временами неадекватно батник может себя вести.
 
2.
Цитата:
переменной присваивается значение, а в следующих строках идёт обработка, но! процессор как будто сразу же "забывает" её значение!

А ты хочешь в одном цикле DO присвоить значение переменной(cueline) и сразу же обкарнать по шесть знаков с каждой стороны этой переменной и присвоить второе значение еще одной переменной(cuefile). Это делается с включением ENABLEDELAYEDEXPANSION. У меня винда сейчас английская, не помню, как там в русской это называется, отложенные переменные чтоли
В общем тоже самое, только переменные пишутся не в знаках процента(%var%), а в восклицательных(!var!) и обрабатываются сразу. Не надо вызывать другую метку в батнике, обрабатывать там, возвращаться... Удобно в общем
 
Попробуй так:

Код:
 
@ECHO OFF  
SETLOCAL ENABLEDELAYEDEXPANSION
 
FOR /F "TOKENS=*" %%f IN ('FINDSTR /B "FILE " %~s1') DO (  
 SET cueline=%%f
 ECHO !cueline!
 SET cuefile=!cueline:~6,-6!
 ECHO !cuefile!  
)
 
ENDLOCAL  
PAUSE
 

 
Добавлено:
Там кстати в *.cue искомая строка всегда FILE<пробел>"имя файла"<пробел>WAVE ?
А то можно проще:

Код:
 
@ECHO OFF  
CD /D %~dps1
FOR /F "TOKENS=2 DELIMS= " %%f IN ('FINDSTR /B "FILE " %~s1') DO SET cuefile=%%f  
ECHO %cuefile%
IF EXIST %cuefile% (ECHO FILE HERE) ELSE (ECHO OOOPS...)
PAUSE
 

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 00:03 08-11-2005 | Исправлено: igor_andreev, 00:53 08-11-2005
jeque

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Подскажите, как в скрипте задать список масок файлов для их последующего копирования. Нашел одно решение, но оно мне не очень нравится.
Cкрипт называется copy_base.cmd и копирует в нужный каталог базы 1С.

Код:
 
@echo off  
if /I exist F:\1c-buch\ goto :_menu
@echo.
@echo Ошибка! Скрипт необходимо запускать непосредственно на сервере.
goto :_end
 
:_menu
cls
@echo.
@echo ****************************************************************
@echo.
@echo  1. Сделать копию базы 1С Бухгалтерский
@echo  2. Сделать копию базы 1С Торговля
@echo  3. Сделать копию базы 1С Бухгалтерский учет 2
@echo  4. Выход
@echo.
@echo ****************************************************************
@echo.
@echo Введите 1,2,3 или 4 и нажмите ввод
 
set /p reply=
if /i "%reply%"=="1" goto :_buh  
if /i "%reply%"=="2" goto :_predpr  
if /i "%reply%"=="3" goto :_uc  
if /i "%reply%"=="4" goto :_end  
goto :_menu
 
:_buh
cls  
set Dest=F:\1c-buh\copy\BUH
set Sour=F:\1c-buh\1cv77\Buid2004
set Prefix=buh-
@echo.
@echo Будет скопирована база 1С Бухгалтерский учет из папки %Sour% в папку %Dest%
@echo Внимание! Все пользватели должны выйти из программы 1С!
@echo Введите "y" для начала копирования или "n" для возврата в меню
@echo.
set /p reply=
if /i "%reply%"=="y" goto :_begin
goto :_menu  
 
:_predpr
cls  
set Dest=F:\1c-buh\copy\PREDPR
set Sour=F:\1c-Predpriyatie\1cv77\id2003
set Prefix=predpr-
@echo.
@echo Будет скопирована база 1С Торговля из папки %Sour% в папку %Dest%
@echo Внимание! Все пользватели должны выйти из программы 1С!
@echo Введите "y" для начала копирования или "n" для возврата в меню
@echo.
set /p reply=
if /i "%reply%"=="y" goto :_begin
goto :_menu  
 
:_uc
cls  
set Dest=F:\1c-buh\copy\UC
set Sour=F:\1c-uch_center\uch\UchCentr_DB_77\1SBDB
set Prefix=uc-
@echo.
@echo Будет скопирована база 1С Бухгалтерский учет из папки %Sour% в папку %Dest%
@echo Внимание! Все пользватели должны выйти из программы 1С!
@echo Введите "y" для начала копирования или "n" для возврата в меню
@echo.
set /p reply=
if /i "%reply%"=="y" goto :_begin
goto :_menu  
 
:_begin

rem *.DBF
rem *.CDX
rem 1CV7.CFG*
rem 1CV7.MD*
rem 1CV7.DD*
rem 1CV7.SPL*
rem 1CV7.ORD*
rem *.SPL*
rem USRDEF\USERS.USR*

if /I not exist %Sour%\1SJOURN.DBF goto :_error
attrib -r %Sour%\1SJOURN.DBF
:_block
attrib +r %Sour%\1SJOURN.DBF
for /f "tokens=1,2 delims=:" %%i in ('attrib %Sour%\1SJOURN.DBF') do set temp_string=%%i
for /f "tokens=1,2,3,4,5,6 delims=ASHC " %%i in ('echo %temp_string%') do if /I NOT "%%i"=="R" goto :_block
for /f "tokens=1,2,3,4,5,6 delims=:./ " %%i in ('"date/t&&time/t"') do if "%%k"=="" (set t=%%i%%j) else set ymd=%%l%%k%%j
set place=%Dest%\%Prefix%%ymd%_%t%\
md %place%

for /f "tokens=1,2 delims= " %%i in (copy_base.cmd) do if "%%i"=="rem" "xcopy" %Sour%\%%j %place%%%j

attrib -r %Sour%\1SJOURN.DBF
goto :_end
 
:_error
@echo.
@echo С базой что-то не так. Не удалось найти файл 1SJOURN.DBF
goto :_end
 
:_end
@echo.
@echo Работа скрипта закончена.
@echo Нажмите любую клавишу.
@echo.
pause>nul
 

 
выделенная часть кода задает маски файлов и копирует их в нужный каталог, но может есть более простое решение, чтобы можно было легко добавлять список масок и при этом, чтобы скрипт не читал сам себя.

Всего записей: 34 | Зарегистр. 29-02-2004 | Отправлено: 10:47 11-11-2005
Smitis



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
jeque

Цитата:
выделенная часть кода задает маски файлов и копирует их в нужный каталог, но может есть более простое решение, чтобы можно было легко добавлять список масок и при этом, чтобы скрипт не читал сам себя.

а почему бы просто не написать:
copy /y *.dbf *.cdx и_т_д папка_куда
На крайний случай несколько команд copy и xcopy?

Всего записей: 2433 | Зарегистр. 09-02-2003 | Отправлено: 15:41 11-11-2005
Da_Neil



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
igor_andreev

Цитата:
Короткое имя файла *.cue то есть, винда все правильно передаст.

У меня короткие имена отключены.  
 

Цитата:
ENABLEDELAYEDEXPANSION

Спасибо за решение, с этим работает. Не подскажешь толковый ресурс по консоли Win, а то про этот ENABLEDELAYEDEXPANSION в справке информации практически ноль.  
 

Цитата:
Там кстати в *.cue искомая строка всегда FILE<пробел>"имя файла"<пробел>WAVE ?  

Не покатит, т.к. пробелы могут быть в имени файлов. Кстати, как приспособить кавычки разделителем? Оба варианта не работают:

Код:
FOR /F "usebackq TOKENS=2 DELIMS=""
FOR /F "usebackq TOKENS=2 DELIMS=^""

Всего записей: 3420 | Зарегистр. 05-03-2002 | Отправлено: 17:57 11-11-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
У меня короткие имена отключены.

Ну и зря. Один какой-то "умник", стопудово никогда батников не писавший, написал в свой статье-опусе, что для ускорения работы системы надо отключать создание коротких имен и все в инете как попки давай за ним повторять это на всех сайтах и другим голову морочить.
Со отключением времени последнего доступа к файлам на NTFS я еще согласен, но короткие имена - нафих-нафих. Имена файлов с символами типа &,!,%,+ и т.п. периодически встречаются и только работать честному командному файлу мешают

Цитата:
про этот ENABLEDELAYEDEXPANSION в справке информации практически ноль.

Да толком то и нету, по всему интернету примеры-инфу выискивать приходиться. Я попробую вкратце описать, чем удобно применение ENABLEDELAYEDEXPANSION. По идее этот топик совсем начинающие батникописатели тоже читают, мож им полегче будет. Тыркайте_сюда
 

Цитата:
Оба варианта не работают:

Хм, у меня тоже не получается . Не сталкивался никогда еще с разделителем-кавычками. Увижу где решение - напишу. Если раньше никто не обьяснит.
 
Добавлено:
jeque
А эта менюшка у тебя корректно показывается, не козябрами? Попробовал только что на компе с русской XP, в реестре которой ничего с кодировками не делали. Пока не напишешь chcp 1251 - русские буквы не отображаются. Вывод то по умолчанию в CP866.

Код:
 
@echo off
chcp 1251
cls
... и т.д.
 

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 16:11 13-11-2005 | Исправлено: igor_andreev, 17:47 13-11-2005
Da_Neil



Silver Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
igor_andreev

Цитата:
Один какой-то "умник", стопудово никогда батников не писавший, написал в свой статье-опусе, что для ускорения работы системы надо отключать создание коротких имен и все в инете как попки давай за ним повторять это на всех сайтах и другим голову морочить.  

Умник случаем не из Microsoft'a?  
 

Цитата:
Имена файлов с символами типа &,!,%,+ и т.п. периодически встречаются и только работать честному командному файлу мешают  

От прогресса не уйдёшь Нужно вырабатывать новые правила работы, а не делать всё по-старинке досовскими методами. Помню, какой-то сумасшедший админ всем советовал не держать ничего в папках с длинными именами, переименовать все системные папки и прочую досовскую ересь..
 

Цитата:
 Да толком то и нету, по всему интернету примеры-инфу выискивать приходиться. Я попробую вкратце описать, чем удобно применение ENABLEDELAYEDEXPANSION. По идее этот топик совсем начинающие батникописатели тоже читают, мож им полегче будет. Тыркайте_сюда  

За примеры спасибо, буду разбираться и копать..  
 
Ещё заметил, что в составном операторе не работают ни обычные комментарии, ни нового типа ( :: ) — скрипт сразу вываливается с ошибкой и прекращает выполнение.
 
Кстати, создавать метку EOF необязательно. Можно использовать оператор GOTO :EOF
 

Всего записей: 3420 | Зарегистр. 05-03-2002 | Отправлено: 20:41 13-11-2005 | Исправлено: Da_Neil, 20:43 13-11-2005
igor_andreev

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
Умник случаем не из Microsoft'a?

Угу, тамошний Сильно performance у тебя с отключением коротких имен повысился? Скажешь - комп летает. Дык он и у меня летает, и еще у кучи народа, не трогающих NtfsDisable8dot3NameCreation в реестре.

Цитата:
От прогресса не уйдёшь

Не в прогрессе дело, а в синтаксисе. Хоть ты кол на голове теши, а например "&" для комстроки - символ конца команды и начало следующей. И для Microsoft Command Shell 2005 года (MSH, которая пока в виде беты, но готовится на замену cmd.exe) - это тоже проблемка есть и будет. Буквально сегодня в MSH скормил wget-у ссылку, заканчивающуюся на  
...Bezumie.(rus).Kinoshniki.&.ShareReactor.ru.avi , не обратил внимания, что там "&". Ну в ответ умная MSH сказала "Missing or invalid property reference or expression. At line:1 char:93". Не идут умники в майкрософт по пути прогресса

Цитата:
Нужно вырабатывать новые правила работы, а не делать всё по-старинке досовскими методами.

И я согласен, и все согласны. И майкрософт так тоже решил и придумал язык с гораздо большими возможностями(VBScript). Ну их, эти батники...

Цитата:
Помню, какой-то сумасшедший админ всем советовал не держать ничего в папках с длинными именами,

Я не админ, но тоже сумасшедший Мне больше нравятся unix-овские названия папок, типа /usr /bin /home. Просто нравятся и мне с такими удобнее.

Цитата:
составном операторе не работают ни обычные комментарии, ни нового типа ( :: )  

Составной оператор - это что? А то я мало того, что не админ, еще и не программист Если внутри DO... имеешь ввиду, то REM точно работает, главное пустых строк не оставлять.

Цитата:
создавать метку EOF необязательно

Угу, по привычке написал. С таким же успехом я мог обозвать метку :END, :KANETZ_FAILA или еще как и тогда ее понадобилось бы создать. Батники просто быстро пишу, ни о чем особо не задумываясь.

Всего записей: 1667 | Зарегистр. 08-12-2004 | Отправлено: 22:18 13-11-2005 | Исправлено: igor_andreev, 22:45 13-11-2005
   

Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)
Widok (19-11-2007 12:08): лимит страниц. продолжаем здесь


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.Board
© Ru.Board 2000-2020

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru