Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Kaspersky Free Anti-Virus | KFA | 365

Модерирует : gyra, Maz

 Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

Открыть новую тему     Написать ответ в эту тему

bifido 76



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Отключение уведомления о регистрации для Kaspersky Free Edition (сохранить в кодировке OEM866, перед запуском отключить самозащиту)
Код:
@echo off
color 17
SetLocal EnableExtensions EnableDelayedExpansion
call :Admin
 
echo.
echo ************************************************************
echo *                                                          *
echo *         Disabling the registration notification          *
echo *                           for                            *
echo *                  Kaspersky Free Edition                  *
echo *                                                          *
echo ************************************************************
echo.
 
rem Определение командной строки нужной разрядности.
if exist %WINDIR%\sysnative\cmd.exe (
    %WINDIR%\sysnative\cmd.exe /c "%~f0"
    goto :eof
)
 
rem Определение разрядности системы
set arch=x64
if "%PROCESSOR_ARCHITECTURE%" == "x86" (
    if not defined PROCESSOR_ARCHITEW6432 set arch=x86
)
 
rem Значение по умолчанию для базового раздела реестра
set "RegBase=HKLM\SOFTWARE\Microsoft\KasperskyLab"
if "%arch%" == "x64" set "RegBase=HKLM\SOFTWARE\Wow6432Node\KasperskyLab"
set "RegTarget=Data\UCPRegistrationAlert"
 
rem Проверка и изменение значения
for /f "delims=" %%r in ('reg query "%RegBase%"  2^>nul ^| find /i "AVP" 2^>nul') do (
    for /f "tokens=3 delims= " %%i in ('reg query "%%~r\%RegTarget%" /v "state" 2^>nul') do (
        if "%%i" == "0x2" (
            echo "Notification is already disabled"
        ) else (
            echo "Try changing the value..."
            rem Отключение нотификации
            reg add "%%~r\%RegTarget%" /v "state" /t REG_DWORD /d 2 /f
            echo.
            rem Проверка значения
            for /f "delims=" %%r in ('reg query "%RegBase%"  2^>nul ^| find /i "AVP" 2^>nul') do (
                for /f "tokens=3 delims= " %%i in ('reg query "%%~r\%RegTarget%" /v "state" 2^>nul') do (
                    if "%%i" == "0x2" (echo "Notification is disabled") else (echo "Notification is not disabled")
                )
            )    
        )
    )
)
pause
goto :eof
 
rem --- Сценарий проверки запуска bat файла с правами Администратора ---
rem --- The script checks if bat file executed with Admin priveleges ---
:Admin
reg query "HKU\S-1-5-19\Environment" >nul 2>&1
if not %errorlevel% EQU 0 (
    cls
    powershell.exe -windowstyle hidden -noprofile "Start-Process '%~f0' -Verb RunAs"
    exit
)
exit /b

Всего записей: 2473 | Зарегистр. 08-04-2016 | Отправлено: 08:18 27-11-2017 | Исправлено: bifido 76, 08:34 27-11-2017
Открыть новую тему     Написать ответ в эту тему

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Kaspersky Free Anti-Virus | KFA | 365


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru