Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)

Модерирует : gyra, Maz

Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6  Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

   

GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Код:
 
set $nlde=^
 
 
rem Don't delete 2 blank lines above
rem ППП GetLen
rem Вычисляет длину строки.
rem Требует предварительного определения $nlde.
rem In:
rem %%a - имя переменной, содержащей строку
rem Out:
rem %%b - имя переменной, в которую будет помещено значение длины
rem Вызов:
rem for /f "tokens=1,2" %%a in ("<string_var> <len_var>") do %GetLen%
set GetLen=^
if defined %%a (^
  (if defined %%b set %%b=)^
& setlocal enabledelayedexpansion^
& for /f %%c in ("4095!$nlde!2048!$nlde!1024!$nlde!512!$nlde!256!$nlde!128!$nlde!64!$nlde!32!$nlde!16!$nlde!8!$nlde!4!$nlde!2!$nlde!1") do (^
    (if !errorlevel! == 1 (set /a %%b-=%%c) else set /a %%b+=%%c)^
&   for %%d in (!%%b!) do if "!%%a:~%%d,1!" == "" (^
      if %%c == 1 (endlocal ^& set %%b=%%d) else color 00^
    ) else (^
      if %%c == 1 (endlocal ^& set /a %%b=%%d+1)^
    )^
  )^
) else (^
  set %%b=0^
)
 

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 15:23 08-07-2018
   

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru