Командная строка, батники, сценарии (bat, cmd) - [2034] :: Программы

Код:

@echo off
SetLocal EnableDelayedExpansion
mode con: cols=90 lines=20
color 17
title Enable-Disable

reg.exe query "HKU\S-1-5-19" >nul 2>&1
if %errorlevel% equ 1 (goto :UACPrompt) else (goto :Enable-Disable)
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~fs0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"
exit /b

:Enable-Disable
cls
Echo Доступны следующие интерфейсы:
Echo.
netsh interface show interface | more +3 | findstr "." | find /n /v ""
Echo.
set N=0
for /f "skip=2 tokens=3*" %%a in ('netsh interface show interface') do set /a N+=1& set Local!N!=%%b
echo Local!N!

:check
set ID=0
set /p "ID=Введите № интерфейса для отключения: "

if %ID% LSS 1 goto :check
if %ID% GTR %N% goto :check

echo.
echo.
CHOICE /C 123 /N /M ">(1- Подключить или 2- Отключить 3- Выйти)"
if %errorlevel%==1 (
cls
echo.
Echo Подключаю !Local%ID%!...
netsh interface set interface name="!Local%ID%!" admin=ENABLED && timeout /t 3 >nul&goto Enable-Disable
)
if %errorlevel%==2 (
cls
echo.
Echo Отключаю !Local%ID%!...
netsh interface set interface name="!Local%ID%!" admin=DISABLED && timeout /t 3 >nul&goto Enable-Disable
)
if %errorlevel%==3 goto :EOF

Pause >NUL
EndLocal
Exit /B

Модерирует : gyra, Maz
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению