Командная строка, батники, сценарии (bat, cmd) - [3142] :: Программы

Код:

@echo off
color F0
pushd "%~dp0"
chcp 1251>nul

setlocal enabledelayedexpansion

set "input=example-dnscrypt-proxy.toml"
set "output=dnscrypt-proxy.toml"

if not exist %input% (
    echo Обрабатываемый файл "%input%" не найден. Для завершения нажмите любую клавишу...
    pause >nul
    exit /b
)

if exist %output% del /q %output%

REM Ищем в нашем файле номер строки [LIST]
for /f "delims=[] tokens=1" %%s in ('find /n "[LIST]" "%~nx0"') do set skip=%%s

echo Начинаем обработку файла "%input%". Подождите...
echo _______________________________________________________________________________________________________
echo.
for /f "tokens=*" %%a in (%input%) do call :pp "%%a"
echo _______________________________________________________________________________________________________
echo.
echo Обработка завершена. Создан файл "%output%" Для завершения нажмите любую клавишу...
pause >nul
exit /b

:pp
set "string=%~1"
REM Из [LIST] ищем уникальные совпадения в строках обрабатываемого файла (до знака $) и если находим, комментируем строку, и после нее выводим то, что за $
for /f "skip=%skip% eol=; tokens=1* delims=$ " %%i in (%~nx0) do (
    echo !string!| find /i "%%i" >nul
    if !errorlevel!==0 (
        echo ## !string! & echo ## !string!>>!output!
        echo %%j & echo %%j>>%output%
        exit /b
    )
) 2>nul
REM Если совпадений не найдено, выводим строку из обрабатываемого файла. Пропускаем закомментированные # строки.
for /f "eol=# tokens=*" %%p in ("!string!") do (
    echo %%p & echo %%p>>%output%
)
exit /b

[LIST]
'scaleway-fr' $ server_names = ['cloudflare']
dnscrypt_servers $ dnscrypt_servers = false
doh_servers $ doh_servers = true
require_dnssec $ require_dnssec = true
fallback_resolver $ fallback_resolver = '1.0.0.1:53'
netprobe_timeout $ netprobe_timeout = 0
netprobe_address $ netprobe_address = '1.0.0.1:53'
block_ipv6 $ block_ipv6 = true
'blacklist.txt' $ blacklist_file = 'blacklist.txt'
'ip-blacklist.txt' $ blacklist_file = 'ip-blacklist.txt'

Модерирует : gyra, Maz
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению