Командная строка, батники, сценарии (bat, cmd) - [3645] :: Программы

Новости • Файловые архивы
Поиск • Активные темы • Топ лист
Правила • Кто в on-line?

Вход • Забыли пароль? • Первый раз на этом сайте? • Регистрация

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)

Модерирует : gyra, Maz
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению

Grachevsky

BANNED

Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

se4a
Вот такой есть образец одним файлом. Список служб внизу.

Код:

@echo off

for /f "delims=:" %%A in ('findstr /xnc:"[Services]" "%~f0"') do set "Skip=%%A"

set Mode=0
call :ServicesHandler

echo 1 - Stop Services
echo 2 - Start Services

:Input
set /p "Mode=Mode: "
for %%M in (1,2) do if %Mode%==%%M goto :Start
goto :Input

:Start
echo.
call :ServicesHandler
echo Done!
pause
exit /b

:ServicesHandler
for /f "usebackq skip=%Skip% tokens=1,2" %%A in ("%~f0") do (
    if "%%A"=="[EOL]" echo. & exit /b
    echo %%A
    if %Mode%==1 (
        sc config %%A start= disabled
        net stop %%A
    )
    if %Mode%==2 (
        sc config %%A start= %%B
        net start %%A
    )
)
exit /b

[Services]
LanmanWorkstation auto
LanmanServer auto
RemoteAccess demand
RemoteRegistry demand
[EOL]

Всего записей: 26 | Зарегистр. 05-03-2020 | Отправлено: 22:37 15-03-2020 | Исправлено: Grachevsky, 04:28 16-03-2020

На первую страницу • к этому сообщению • к последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6

Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC