@rem :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@rem :: Script: RunFFplay.bat ::
@rem :: Version: 1.1 from 25.01.2018 ::
@rem :: Description: Run the ffplay.exe in different modes defined ::
@rem :: by the file format ::
@rem :: TC Parameters: "%p%n" (match case!) ::
@rem :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off
set /a init=%TIME:~0,2%*360000+%TIME:~3,2%*6000+%TIME:~6,2%*100+%TIME:~9,2%
(set /p sTitle=<"%~dp0\ffmpeg.ver")2>nul
if not defined sTitle (
set sTitle=FFmpeg
) else (set sTitle=FFmpeg build %sTitle%)
title %sTitle%
set sPlay=-: q, Esc :: p, Spc :: left/right :: up/down :: 0/9 :: ^
m :: f :: w :: s :-
set AudioExt=aac,ac3,act,adts,aea,aiff,alaw,ape,ast,au,avr,boa,caf,daud,eac3,^
epaf,f32be,f32le,f64be,f64le,flac,ircam,loas,m4a,mj2,mlp,mmf,mp2,mp3,mpc,mpc8,^
mulaw,oga,ogg,oma,s16be,s16le,s24be,s24le,s32be,s32le,s8,shn,speex,tedcaptions,^
tta,u16be,u16le,u24be,u24le,u32be,u32le,u8,voc,w64,wav,wma,wsaud,wv,xwma
set VideoExt=3g2,3gp,a64,amr,applehttp,asf,asf_stream,avi,avm2,cavsvideo,cdxl,^
dshow,dts,dtshd,dv,dvd,ea,f4v,film_cpk,filmstrip,flic,flv,gif,h261,h263,h264,^
hevc,hls,idcin,iff,ipmovie,ipod,iv8,m2t,m4v,mjpeg,mkv,mlv,mov,mp4,mpeg,^
mpeg1video,mpeg2video,mpegts,mpegtsraw,mpegvideo,mpg,msnwctcp,mts,mtv,mv,mvi,^
mxf,mxf_d10,mxg,nc,nsv,null,nuv,paf,psp,rawvideo,rm,rpl,svcd,swf,vc1,vc1test,^
vcd,vfwcap,vob,wc3movie,webm,webm,wmv,wtv,xmv
set FileExt=%~X1
set FileExt=%FileExt:.=%
for %%e in (%AudioExt%) do (
if /i %%e==%FileExt% (
ffplay.exe -hide_banner -autoexit -x 750 -y 130 -window_title "%sPlay%" %1
goto :checking
)
)
for %%e in (%VideoExt%) do (
if /i %%e==%FileExt% (
ffplay.exe -hide_banner -autoexit -window_title "%sPlay%" %1
goto :checking
)
)
set report=UNKNOWN FILE FORMAT
:report
cls
echo. & echo.
%NIRCMDC_EXE% setconsolecolor 0 12
echo %report%
%NIRCMDC_EXE% setconsolecolor 10 0
echo. & echo. & echo FFPlay.exe report:
echo ------------------------------------------------------------------------
echo. & echo.
%NIRCMDC_EXE% setconsolecolor 7 0
ffplay.exe -hide_banner -autoexit -window_title "%sPlay%" %1
%NIRCMDC_EXE% setconsolecolor 10 0
echo. & echo.
echo ------------------------------------------------------------------------
echo. & echo Edit the section of extensions in the RunFFplay.bat if necessary
%NIRCMDC_EXE% setconsolecolor 7 0
echo. & echo Press any key to exit ...
pause>nul
exit
:checking
set /a term=%TIME:~0,2%*360000+%TIME:~3,2%*6000+%TIME:~6,2%*100+%TIME:~9,2%
set /a diff=%term%-%init%
if %diff% LSS 0 goto :EOF
if %diff% LSS 80 (set report=PLAY ERROR) & goto :report
exit
|
