RetroRocket
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: @echo off
title Serpent
rem ===== Диапазон значений ширины. ==========
set MINW=1200
set MAXW=1450
rem ===== Диапазон значений высоты. ==========
set MINH=700
set MAXH=830
rem ==========================================
rem ==== Проверяем наличие файлов \FirefoxPortable.ini и \FirefoxPortable.exe.
if not exist "%~dp0FirefoxPortable.ini" echo Error: file FirefoxPortable.ini not found. Press any key to exit.&&pause>nul&&exit /b 1
if not exist "%~dp0FirefoxPortable.exe" echo Error: file FirefoxPortable.exe not found. Press any key to exit.&&pause>nul&&exit /b 1
rem ==== Исключаем двойной запуск.
tasklist|find /i "basilisk.exe">nul
if %errorlevel% equ 0 echo Error: basilisk.exe already running. Press any key to exit.&&pause>nul&&exit /b 1
rem ==== Пропускаем первый random.
echo %random% >nul
rem ==== Вычисляем размеры.
set /a W=MINW+(MAXW-MINW+1) * %random%/32768
set /a H=MINH+(MAXH-MINH+1) * %random%/32768
rem ==== Добавляем новые значения ширины и высоты в строку AdditionalParameters файла FirefoxPortable.ini.
type "%~dp0FirefoxPortable.ini"|findstr /v /i "AdditionalParameters">"%~dp0FirefoxPortable.ini.tmp"
echo AdditionalParameters=-width %W% -height %H%>>"%~dp0FirefoxPortable.ini.tmp"
move /y "%~dp0FirefoxPortable.ini.tmp" "%~dp0FirefoxPortable.ini"
rem ==== Проверяем имя текущего пользователя.
if /i "%USERNAME%" == "Test_User" (%WINDIR%\dmr.exe %~dp0FirefoxPortable.exe&&exit /b 0)
rem ==== Проверяем название компьютера.
echo HP_VM1 HP_SRV IBM_TEST COMPAQ_D51|find /i "%COMPUTERNAME%">nul
if %errorlevel% equ 0 (%WINDIR%\system32\runas.exe /savecred /user:%COMPUTERNAME%\Test_User "%WINDIR%\dmr.exe %~dp0FirefoxPortable.exe"&&exit /b 0
) else (%WINDIR%\dmr.exe %~dp0FirefoxPortable.exe&&pause&&exit /b 0)
|
|
Всего записей: 2685 | Зарегистр. 02-01-2018 | Отправлено: 15:31 21-09-2020 | Исправлено: RetroRocket, 07:14 22-09-2020 |
|
