Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd

Модерирует : gyra, Maz

 Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

Открыть новую тему     Написать ответ в эту тему

WiperX



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off
setlocal enabledelayedexpansion
 
for /F "tokens=1,2*" %%i in ('reg query HKLM\Software\7-Zip /v Path') do (
    set "PATH=%%k;%PATH%"
)
 
7z >NUL
if not %errorlevel% == 0 (
    echo 7z.exe is required
    goto end
)
 
if not "%~1" == "" (
    set "installer=%~1"
) else if exist iTunes6464Setup.exe (
    set installer=iTunes6464Setup.exe
) else if exist iTunes64Setup.exe (
    set installer=iTunes64Setup.exe
) else if exist iTunesSetup.exe (
    set installer=iTunesSetup.exe
) else if exist QuickTimeInstaller.exe (
    set installer=QuickTimeInstaller.exe
) else (
    echo installer executable not found
    goto end
)
 
7z e -y "%installer%" iTunes64.msi
 
)
if exist iTunes64.msi (
    call :extract QTfiles64 iTunes64.msi
)
goto end
 
:extract
mkdir %1
 
7z l -i!CoreAudioToolbox.* %2 | findstr CoreAudioToolbox
 
if errorlevel 1 (
    7z e -y -o%1 ^
             -i^^!fil84AEB850B33D669F6CF5102EB0C4C575 ^
             -i^^!fil7C581B08BA4DCF9C9D6CE8C73004B1D3 ^
             -i^^!fil31C8F76E8C290A62E9C9587D6CC5E55F ^
             -i^^!fil6F17A3C1846C9728E043CA9170A2DE47 ^
             -i^^!filA069D5D000A020343C6E7AB6FF3C4039 ^
             -i^^!fil91A06D0D13828CCF3AACE9DE43D98C10 ^
             -i^^!fil40BDB85D846A9E26183C1B4897E354B6 ^
             -i^^!fil501C29C9A9E8877F7F0E1684A2302DE7 ^
             -i^^!*iTunes64_icudt*.dll ^
             -i^^!F_CENTRAL_msvc?100* ^
             -i^^!F_CENTRAL_msvc?120* ^
             -i^^!vcruntime140.dll* ^
             -i^^!msvcp140.dll* ^
             -i^^!concrt140.dll* ^
             -i^^!api_ms_win* ^
             -i^^!ucrtbase* ^
             %2
 
    pushd %1
    for %%f in (iTunes64_*.dll) do (
        for /F "tokens=1* delims=_ " %%t in ("%%f") do move /Y %%f %%u
    )
    for %%f in (x64_iTunes64_*.dll) do (
        for /F "tokens=2* delims=_ " %%t in ("%%f") do move /Y %%f %%u
    )
 
    for %%f in (F_CENTRAL_msvcr100*) do move /Y %%f msvcr100.dll
    for %%f in (F_CENTRAL_msvcp100*) do move /Y %%f msvcp100.dll
    for %%f in (F_CENTRAL_msvcr120*) do move /Y %%f msvcr120.dll
    for %%f in (F_CENTRAL_msvcp120*) do move /Y %%f msvcp120.dll
    for %%f in (vcruntime140*) do (
        for /F "tokens=1 delims=." %%t in ("%%f") do move /Y %%f %%t.dll
    )
    for %%f in (msvcp140*) do (
        for /F "tokens=1 delims=." %%t in ("%%f") do move /Y %%f %%t.dll
    )
    for %%f in (concrt140*) do (
        for /F "tokens=1 delims=." %%t in ("%%f") do move /Y %%f %%t.dll
    )
    for %%f in (ucrtbase*) do (
        for /F "tokens=1 delims=." %%t in ("%%f") do move /Y %%f %%t.dll
    )
    for %%f in (api_ms_win*) do (
        for /F "tokens=1 delims=." %%t in ("%%f") do (
            set NAME=%%t
            move /Y %%f !NAME:_=-!.dll
        )
    )
    popd
) else (
 
    mkdir %1\Microsoft.VC80.CRT
 
    7z e -y -oQTfiles\Microsoft.VC80.CRT ^
            -i^^!msvcp80.dll.* ^
            -i^^!msvcr80.dll.* ^
            -i^^!manifest.* ^
            iTunes64.msi
 
    pushd %1\Microsoft.VC80.CRT
 
    rem strip assembly version number from filenames of msvc runtime dlls
    for %%f in (msvcr80.dll.*) do move /Y %%f msvcr80.dll
    for %%f in (msvcp80.dll.*) do move /Y %%f msvcp80.dll
 
    rem find needless one out of the two manifests and remove it
    for /F "delims=:" %%t in ('findstr win32-policy manifest.*') do del %%t
 
    rem rename manifest
    for %%f in (manifest.*) do move /Y %%f Microsoft.VC80.CRT.manifest
 
    popd
)
exit /b
 
:end
if exist iTunes64.msi del iTunes64.msi
Ren QTfiles64\fil84AEB850B33D669F6CF5102EB0C4C575 ASL.dll
Ren QTfiles64\fil7C581B08BA4DCF9C9D6CE8C73004B1D3 libdispatch.dll
Ren QTfiles64\fil31C8F76E8C290A62E9C9587D6CC5E55F objc.dll
Ren QTfiles64\fil6F17A3C1846C9728E043CA9170A2DE47 libicuuc.dll
Ren QTfiles64\filA069D5D000A020343C6E7AB6FF3C4039 CoreFoundation.dll
Ren QTfiles64\fil91A06D0D13828CCF3AACE9DE43D98C10 libicuin.dll
Ren QTfiles64\fil40BDB85D846A9E26183C1B4897E354B6 CoreAudioToolbox.dll
Ren QTfiles64\fil501C29C9A9E8877F7F0E1684A2302DE7 icudt62.dll
endlocal

Всего записей: 960 | Зарегистр. 17-03-2009 | Отправлено: 23:13 08-12-2022 | Исправлено: WiperX, 23:15 08-12-2022
Открыть новую тему     Написать ответ в эту тему

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru