Victor_VG
Tracker Mod | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off
if "%~1" == "-h" (goto hlp)
if "%~1" == "--help" (goto hlp)
if "%~1" == "help" (goto hlp)
if "%~2" == "" (goto error)
if "%~1" == "" (goto error)
if exist 7-zip (move /y 7-Zip 7-Zip.old > nul)
for %%A in (
7z%1%2-arm64.exe
7z%1%2-extra.7z
7z%1%2-linux-arm.tar.xz
7z%1%2-linux-arm64.tar.xz
7z%1%2-linux-x64.tar.xz
7z%1%2-linux-x86.tar.xz
7z%1%2-mac.tar.xz
7z%1%2-src.7z
7z%1%2-src.tar.xz
7z%1%2-x64.exe
7z%1%2-x64.msi
7z%1%2.exe
7z%1%2.msi
7zr.exe
lzma%1%2.7z
) do curl -C - -LRSs --create-dirs --output 7-Zip\%%A https://www.7-zip.org/a/%%A
exit
:error
echo Required parameters 1 and 2 - version number like is 18 05 not defined & pause & exit /b
:hlp
echo.
echo Synopsis:
echo.
echo This script is download 7-Zip botch EXE and MSI installer,
echo 7-Zip Extras, 7-Zip Source and LZMA SDK.
echo.
echo Usage:
echo.
echo 7zdn ^<version_major^> ^<version_minor^>
echo.
echo Examples:
echo.
echo 7zdn 18 04 or 7zdn 18 05 or 7zdn -h or 7zdn --help or 7zdn help
echo.
echo Switches:
echo.
echo -h , --help , help - is this help display and exit
echo.
pause
exit /b |
Всего записей: 33272 | Зарегистр. 31-07-2002 | Отправлено: 14:53 20-06-2023 | Исправлено: Victor_VG, 07:57 21-06-2023 |
|
