Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Операционные системы » Microsoft Windows » Задачи на bat-файлах 9

Модерирует : KLASS, IFkO

vu1tur (09-01-2011 11:53): лимит страниц, продолжение — http://forum.ru-board.com/topic.cgi?forum=62&topic=22143  Версия для печати • ПодписатьсяДобавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101

   

vu1tur



Moderator-Saaber
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Задачи на bat-файлах 9
(часть 1, часть 2, часть 3, часть 4, часть 5, часть 6, часть 7, часть 8)
Вопросы, задачи и их решения по работе с командными файлами, а также сопутствующие ссылки.

 
Важно: копируя батник через буфер обмена из форума не забывайте удалять пробелы в конце каждой строки, т.к. в некоторых случаях из-за этого программа будет работать неправильно!!!
 
Также для удаления концевых пробелов пользуйтесь скриптом от Nagual, или VBS-Скрипт-Модулем от ViSiToR.
 
Для перекодирования кирилицы 866<—>1251 пользуйтесь онлайн сервисом Перекодировщик кириллицы

 
Дополняем шапку: добавляем готовые решения, полезные ссылки.
 
Примечание: Большие куски кода заключайте в тэг [more]  
 
Смежные темы:
В помощь системному администратору » Автоматизация администрирования
Программы » Командная строка, батники\сценарии
 
Полезные ссылки
 
Полезные утилиты
 
Готовые решения и частые вопросы:
  • Встроенный справочник по командам
  • Создание помощи по всем командам консоли 2000 и XP
  • Делаем паузу в командном файле стандартными средствами Windows
  • Альтернативные решения »
  • Работа с текстом, датой, и файлами »
  • Администрирование, автоматизация и сеть »
  • Работа с переменными и параметрами ком. строки »
     
    Описания работы команд и символов участниками темы:
    · setlocal enabledelayedexpansion и переменные окружения
    · символы & и && в командной строке
    · Переменная %0

  • Всего записей: 3690 | Зарегистр. 01-02-2003 | Отправлено: 17:45 04-09-2010 | Исправлено: Accessor, 18:04 28-09-2010
    Vladins

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    king_stiven Работает. Благодарю

    Всего записей: 68 | Зарегистр. 22-05-2010 | Отправлено: 00:11 24-12-2010
    vbrv

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Rush, спасибо за помощь.
     
    Помогите допилить скрипт.
    Нашёл пример генерации пароля.

    Код:
    @echo off
    setlocal
     
    for /l  %%i in (1,1,32) do (
        for %%i in (a,b,c,d,e,f,0,1,2,3,4,5,6,7,8,9) do call:set %%i
        for /f "tokens=3 delims=_=" %%i in ('set sign_') do set "str=%%i"
        call:string
    )
     
    echo %string%
     
    goto:eof
     
    :set
    set "sign_%random%=%1"
    goto:eof
     
    :string
    set "string=%string%%str%"
    for /f "tokens=1 delims==" %%i in ('set sign_') do set "%%i="

     
    Но не могу допетрить как это перевести в функцию, для вызова из цикла.

    Код:
    FOR /F "tokens=*" %%i in (list.txt) do (
      вызов функции генерации пароля
      7z a -t7z -mx5 -p%string% %%i.7z %%i*
    )

    Всего записей: 62 | Зарегистр. 01-02-2009 | Отправлено: 10:14 24-12-2010 | Исправлено: vbrv, 10:18 24-12-2010
    res2001



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    vbrv

    Цитата:
    как это перевести в функцию, для вызова из цикла.  

    Видимо так:

    Код:
    @echo off
    FOR /F "tokens=*" %%a in (list.txt) do (
      call:getpass
      7z a -t7z -mx5 -p%string% %%a.7z %%a*
    )
    goto:eof
     
    :getpass
    for /l  %%i in (1,1,32) do (
        for %%j in (a,b,c,d,e,f,0,1,2,3,4,5,6,7,8,9) do call:set %%j
        for /f "tokens=3 delims=_=" %%j in ('set sign_') do set "str=%%j"
        call:string
    )
    echo.%string%
    exit /b
     
    :set
    set "sign_%random%=%1"
    exit /b
     
    :string
    set "string=%string%%str%"
    for /f "tokens=1 delims==" %%j in ('set sign_') do set "%%j="
    exit /b

    Всего записей: 2580 | Зарегистр. 11-04-2003 | Отправлено: 10:46 24-12-2010 | Исправлено: res2001, 10:49 24-12-2010
    vbrv

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Не правильно работает.
    Для теста заменил 7z на вывод в консоль:

    Код:
    @echo off
     
    for /l  %%z in (1,1,3) do (
      call:getpass
      echo %string%
    )
    goto:eof
     
    :getpass
    for /l  %%i in (1,1,32) do (
      for %%j in (a,b,c,d,e,f,0,1,2,3,4,5,6,7,8,9) do call:set %%j
      for /f "tokens=3 delims=_=" %%j in ('set sign_') do set "str=%%j"
      call:string
    )
    echo.%string%
    exit /b
     
    :set
    set "sign_%random%=%1"
    exit /b
     
    :string
    set "string=%string%%str%"
    for /f "tokens=1 delims==" %%j in ('set sign_') do set "%%j="
    exit /b

     
    Чёрт с ним, я лучше нашёл генератор:

    Код:
    @echo off & setlocal enableextensions enabledelayedexpansion
     
    rem This script file is part of the following collection:
    rem   ftp://garbo.uwasa.fi/pc/link/tscmd.zip
    rem   http://garbo.uwasa.fi/pub/pc/link/tscmd.zip
    rem   Useful NT/2000/XP script tricks and tips, T.Salmi
    rem Please do not distribute separately from that package.
    rem
    rem Also see http://www.netikka.net/tsneti/info/tscmd.php
    rem for an HTML version of Assorted NT/2000/XP/.. CMD.EXE Script Tricks
     
    echo.
    echo ЪДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДї
    echo і MAKEPASS.CMD Make a randomized password           і
    echo і By Prof. Timo Salmi, Last modified Tue 2-Feb-2010 і
    echo АДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДЩ
    echo.
     
    :: Is help asked for
    if "%~1"=="?" goto _help
    if "%~1"=="/?" goto _help
     
    :: Set your desired password length
    set PasswordLength=10
     
    :: The character set to be drawn from
    set chars=abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789@#/()=+-,.;:_*'
    rem       0123456789 123456789 123456789 123456789 123456789 123456789 123456789 123456
    rem echo %chars%
    rem echo 0123456789 123456789 123456789 123456789 123456789 123456789 123456789 1234567
     
    :: Requirements on the password
    if "%~1"=="" set MaxChar=76
    if "%~1"=="/1" set MaxChar=25
    if "%~1"=="/2" set MaxChar=51
    if "%~1"=="/3" (
      set MaxChar=61
      set RequireNumber=true
      )
    if "%~1"=="/4" (
      set MaxChar=76
      set RequireNumber=true
      set RequireSpecial=true
      )
     
    :: Build the password
    :_again
    set result_=
    for /L %%i in (1,1,%passwordLength%) do (
      call :GetOneRandomChar %MaxChar% rndchr_
      set result_=!result_!!rndchr_!
      )
     
    :: Are the requirements met?
    echo %result_%|findstr "[0123456789]">nul
    if %errorlevel% EQU 0 set FoundNumber=true
    echo %result_%|findstr "[@#/()=+-,.;:_*']">nul
    if %errorlevel% EQU 0 set FoundSpecial=true
    if defined RequireNumber if not defined FoundNumber goto _again
    if defined RequireSpecial if not defined FoundSpecial goto _again
     
    :: Display the resulting random password
    echo %result_%
    goto _out
     
    :_help
    echo Usage: MAKEPASS [/Choiceі/?]
    echo.
    echo /1 only lower-case letters
    echo /2 only letters
    echo /3 require at least one number
    echo /4 require at least one number and one special character
    echo None: No preference
    goto _out
     
    :_out
    if not defined cmdbox if defined PauseIfFromDesktop pause
    endlocal & goto :EOF
     
    :: ============================================================
    : GetOneRandomChar MaxChar
    setlocal enableextensions enabledelayedexpansion
    set /a div_=32767 / %1
    set /a rand_=%random% / %div_%
    set return_=!chars:~%rand_%,1!
    endlocal & set "%2=%return_%" & goto :EOF

    Хотелось бы этот бат файл вызывать из основного батника и соответственно получать из него сгенерированный пароль.
    На сколько я понял, если бы не setlocal, то я бы в основном батнике мог получить пароль через переменную %return_%.
    Пробовал экспериментировать с setlocal, но добился только неработоспособности скрипта.
     
    Опять прошу помощи...

    Всего записей: 62 | Зарегистр. 01-02-2009 | Отправлено: 13:19 24-12-2010 | Исправлено: vbrv, 13:20 24-12-2010
    res2001



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    vbrv

    Цитата:
    Не правильно работает.

    В чем неправильность? Я у себя тестировал - работает.
     

    Цитата:
    Хотелось бы этот бат файл вызывать из основного батника и соответственно получать из него сгенерированный пароль.  

    Ну и вызывай:
    for /f "skip=4 tokens=*" %%a in ('MAKEPASS.CMD') do set pass=%%a

    Всего записей: 2580 | Зарегистр. 11-04-2003 | Отправлено: 13:48 24-12-2010
    vbrv

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    res2001

    Цитата:
    В чем неправильность? Я у себя тестировал - работает.  

    После каждой итерации цикла новый пароль дописыватся к старому.
    Надо как-то обнулять переменную string.
    Даже после выхода из батника и запуска его вновь, новый пароль добавляется к концу пароля из прошлой отработки батника.
    1 итерация: pass=12
    2 итерация: pass=1234
    3 итерация: pass=123456
    выход из батника и его повторный запуск:
    pass=12345678
    .....
     

    Цитата:
    for /f "skip=4 tokens=*" %%a in ('MAKEPASS.CMD') do set pass=%%a  

    Спасибо, работает, только поправил skip=5
    Здесь тоже переменная не обнуляется после выхода из батника.
     

    Код:
    @echo off
    for /f "skip=5 tokens=*" %%a in ('MAKEPASS.CMD') do (
      set %pass%=%%a
      echo %pass%
    )

    После одного запуска, все остальные выводят один и тот же пароль.
     
    Добавлено:
    затупил
    "set %pass%=%%a", pass надо без %% писать.
     
    Добавлено:
    Нашёл как обнулять set "string=", теперь первый скрипт работает как надо.

    Код:
    @echo off
     
    for /l  %%z in (1,1,3) do (
      call:getpass
      echo %string%
      set "string="
    )
    .......

    Всего записей: 62 | Зарегистр. 01-02-2009 | Отправлено: 23:23 24-12-2010 | Исправлено: vbrv, 00:29 25-12-2010
    wolf0425



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Цитата:
    затупил
    "set %pass%=%%a", pass надо без %% писать.

    ещё затупил в
    Код:
     do (
      set pass=%%a
      echo %pass%
    )  
    надо
    Код:
    do (
      set pass=%%a
    )  
    echo %pass%
     
    или будешь иметь печать того %pass% что был до вызова for

    Всего записей: 2920 | Зарегистр. 25-04-2007 | Отправлено: 00:35 25-12-2010 | Исправлено: wolf0425, 00:36 25-12-2010
    vbrv

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Цитата:
    или будешь иметь печать того %pass% что был до вызова for

    Спасибо, правда непонятно почему так будет.
     
    С похожей ситуацией справиться не могу.

    Код:
    @echo off
    setlocal enabledelayedexpansion
     
    for /l  %%z in (1,1,3) do (
      for /f "skip=5 tokens=*" %%a in ('MAKEPASS.CMD') do set pass=%%a
      @echo !pass!
    )

    На выходе получаю когда три одинаковых пароля, когда два из трёх.

    Всего записей: 62 | Зарегистр. 01-02-2009 | Отправлено: 00:55 25-12-2010
    wolf0425



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Цитата:
    Спасибо, правда непонятно почему так будет.  
    потому что все %переменные% в операторе for (включая те что в do) будут заменены на значения ещё в момент разбора интерпретатором команды - до начала выполнения for
    плюс полностью аналогичная ситуация с операторами в (скобках), которые тоже препроцессятся целиком - а у тебя там и скобки и for разом
     

    Цитата:
    С похожей ситуацией справиться не могу.  
    btw, текст MAKEPASS.CMD приведи...
    но скорее всего тут ситуация не похожая, а совсем другая - типа попадало на фиговую рандомность %random% при последовательных вызовах батника.

    Всего записей: 2920 | Зарегистр. 25-04-2007 | Отправлено: 01:38 25-12-2010 | Исправлено: wolf0425, 10:12 25-12-2010
    vbrv

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Код:
    @echo off & setlocal enableextensions enabledelayedexpansion
     
    rem This script file is part of the following collection:
    rem   ftp://garbo.uwasa.fi/pc/link/tscmd.zip
    rem   http://garbo.uwasa.fi/pub/pc/link/tscmd.zip
    rem   Useful NT/2000/XP script tricks and tips, T.Salmi
    rem Please do not distribute separately from that package.
    rem
    rem Also see http://www.netikka.net/tsneti/info/tscmd.php
    rem for an HTML version of Assorted NT/2000/XP/.. CMD.EXE Script Tricks
     
    echo.
    echo ЪДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДї
    echo і MAKEPASS.CMD Make a randomized password           і
    echo і By Prof. Timo Salmi, Last modified Tue 2-Feb-2010 і
    echo АДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДДЩ
    echo.
     
    :: Is help asked for
    if "%~1"=="?" goto _help
    if "%~1"=="/?" goto _help
     
    :: Set your desired password length
    set PasswordLength=10
     
    :: The character set to be drawn from
    set chars=abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789@#/()=+-,.;:_*'
    rem       0123456789 123456789 123456789 123456789 123456789 123456789 123456789 123456
    rem echo %chars%
    rem echo 0123456789 123456789 123456789 123456789 123456789 123456789 123456789 1234567
     
    :: Requirements on the password
    if "%~1"=="" set MaxChar=76
    if "%~1"=="/1" set MaxChar=25
    if "%~1"=="/2" set MaxChar=51
    if "%~1"=="/3" (
      set MaxChar=61
      set RequireNumber=true
      )
    if "%~1"=="/4" (
      set MaxChar=76
      set RequireNumber=true
      set RequireSpecial=true
      )
     
    :: Build the password
    :_again
    set result_=
    for /L %%i in (1,1,%passwordLength%) do (
      call :GetOneRandomChar %MaxChar% rndchr_
      set result_=!result_!!rndchr_!
      )
     
    :: Are the requirements met?
    echo %result_%|findstr "[0123456789]">nul
    if %errorlevel% EQU 0 set FoundNumber=true
    echo %result_%|findstr "[@#/()=+-,.;:_*']">nul
    if %errorlevel% EQU 0 set FoundSpecial=true
    if defined RequireNumber if not defined FoundNumber goto _again
    if defined RequireSpecial if not defined FoundSpecial goto _again
     
    :: Display the resulting random password
    echo %result_%
    goto _out
     
    :_help
    echo Usage: MAKEPASS [/Choiceі/?]
    echo.
    echo /1 only lower-case letters
    echo /2 only letters
    echo /3 require at least one number
    echo /4 require at least one number and one special character
    echo None: No preference
    goto _out
     
    :_out
    if not defined cmdbox if defined PauseIfFromDesktop pause
    endlocal & goto :EOF
     
    :: ============================================================
    : GetOneRandomChar MaxChar
    setlocal enableextensions enabledelayedexpansion
    set /a div_=32767 / %1
    set /a rand_=%random% / %div_%
    set return_=!chars:~%rand_%,1!
    endlocal & set "%2=%return_%" & goto :EOF

     

    Всего записей: 62 | Зарегистр. 01-02-2009 | Отправлено: 01:42 25-12-2010
    wolf0425



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    vbrv угу, это именно глюки %random% который повторяется если его часто пересбрасывать.
    впиши ping localhost -n 2 >nul  в начало MAKEPASS.CMD (или в for между вызовами) - это затянет каждую генерацию на секунду, но зато все пароли будут разные.
     
    ну или засовывай код MAKEPASS.CMD в свой батник и переписывай чтоб был вызов без запуска нового cmd

    Всего записей: 2920 | Зарегистр. 25-04-2007 | Отправлено: 09:05 25-12-2010 | Исправлено: wolf0425, 11:11 25-12-2010
    pav461

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Помогите, пожалуйста с bat файлом. Текст задания:
    Вывести на экран монитора квадрат наименьшего из значений трех параметров а1, а2, а3 или сообщение "Параметры равны", если значения параметров равны.

    Всего записей: 25 | Зарегистр. 27-02-2009 | Отправлено: 11:33 25-12-2010
    01MDM



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    pav461
    Домашка?

    Код:
     
    @echo off
    setlocal enabledelayedexpansion
    1>nul chcp 1251
     
    if %1==%2 (if %2==%3 echo Параметры равны && goto:eof)
     
    set "param=%1"
    for %%i in (%*) do if %%i leq !param! set "param=%%i"  
     
    for /l %%i in (0,1,%param%) do (
        
        set /a test=%%i*%%i
        if !test! leq %param% set "sqrt=%%i"
     
    )
     
    echo %sqrt%
     

    Подразумевается что параметры положительные целые числа, имеющие целый корень (0, 1, 4, 9, 16 и т.д.)


    ----------
    Вопросы в личке останутся без ответа

    Всего записей: 2638 | Зарегистр. 13-02-2006 | Отправлено: 12:50 25-12-2010 | Исправлено: 01MDM, 13:09 25-12-2010
    pav461

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    01MDM, спасибо. Да, домашка, за неделю до нового года мозг отказался делать последнюю лабу...

    Всего записей: 25 | Зарегистр. 27-02-2009 | Отправлено: 13:11 25-12-2010
    wolf0425



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    01MDM, в задаче просили квадрат наименьшего, а не квадратный корень из наименьшего

    Всего записей: 2920 | Зарегистр. 25-04-2007 | Отправлено: 14:40 25-12-2010
    01MDM



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    А я еще подумал, что какое-то сложное для cmd задание. Ну я вижу парень грамотный, подправит..

    Всего записей: 2638 | Зарегистр. 13-02-2006 | Отправлено: 15:13 25-12-2010
    Lamman



    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    wolf0425
    res2001
     
    Спасибо!
     
    Упростил схему распределения переменных.
    Заработало... Их распределение.
     
    Заодно вспомнил, почему я ещё при первом преближении отсеял такой сценакрий как неработающий.
    Это же текстовые строки 02, 09 и т.д., а не числа.
    Так что обрабатывать их нужно как текстовые строки, либо писать на чём-нибудь ещё.
     
    [лирическое отступление]
    Скрипты предложенные представляют интерес... Хотелось бы только по vbs'у какой-нибудь учебник что ли... Мне лично для понимания больше всего подходят "классические университетсвие"... Не подскажет кто-нибудь, какую-нибудь содержательную книгу в этой связи?..
    [/лирическое отступление]
     
    На avtoIt'е такая процедура занимает буквально пару строк и используется во всех тривиальных "загрузчиках" программ, проявляющих интерес к дате...

    Всего записей: 22 | Зарегистр. 23-04-2010 | Отправлено: 14:20 26-12-2010
    wolf0425



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Цитата:
    На avtoIt'е такая процедура занимает буквально пару строк и используется во всех тривиальных "загрузчиках" программ, проявляющих интерес к дате...

    ну так и на vbs это занимает строку из двух операторов, плюс ещё оператор и строка создание vbs  и его вызов...
    не изобретай велосипед
     
    а за ссылками на мануал по скриптингу сходи в соответствующую тему
    те что там в шапке - уже сдохли, но может обновят, да и в самой теме какие-то ссылки проскакивали...
     

    Всего записей: 2920 | Зарегистр. 25-04-2007 | Отправлено: 16:02 26-12-2010 | Исправлено: wolf0425, 16:03 26-12-2010
    Lamman



    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    pav461
     
    Сравнение можно провести ещё как-нибудь так:
     

    Код:
    if %a1% leq %a2% (set num=%a1%) else (set num=%a2%)
    if %num% leq %a3% (set x=%num%) else (set x=%a3%)
    set /a "%sq%=x*x"

     
    Возможно добавив переход на следующий шаг по call.
    Хотя через for, наверное, изящней.
     
    01MDM
     
    Не вполне понятно, правда, зачем нужна эта часть:
     

    Код:
    for /l %%i in (0,1,%param%) do (
        set /a test=%%i*%%i
        if !test! leq %param% set "sqrt=%%i"
    )

     
    Она возвращает квадратный корень... Но зачем такая процедура? Зачем получать квадрат...
    Так. Гм. Всё понятно.
    Правда тогда получается довольно грубое приближение для всех нечётных чисел за счёт "меньше/равно" и шага в "1".
    Есть ли возможность задать в качестве шага дробь?..

    Всего записей: 22 | Зарегистр. 23-04-2010 | Отправлено: 17:02 26-12-2010 | Исправлено: Lamman, 17:55 26-12-2010
    01MDM



    Silver Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Lamman,
    Я просто ошибся с заданием  
     
    Я, думаю можно, но заморачиваться не стоит. Вот ~приблизительное, неторопливое псевдорешение:

    Код:
     
    @echo off
    setlocal enabledelayedexpansion
     
    echo %time%
    set "n=%1"
     
    for /l %%i in (0,1,%n%00000) do (
     
        set /a test=%%i*%%i
        if !test! leq %n%0000 (set "sqrt=%%i") else (goto:echo)
     
    )
     
    :echo
    echo %sqrt:~0,-2%.%sqrt:~-2%
    echo %time%
     
    :: И проверка:
    powershell -c [math]::sqrt(%n%)
     

     


    ----------
    Вопросы в личке останутся без ответа

    Всего записей: 2638 | Зарегистр. 13-02-2006 | Отправлено: 23:45 26-12-2010
       

    Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101

    Компьютерный форум Ru.Board » Операционные системы » Microsoft Windows » Задачи на bat-файлах 9
    vu1tur (09-01-2011 11:53): лимит страниц, продолжение — http://forum.ru-board.com/topic.cgi?forum=62&topic=22143


    Реклама на форуме Ru.Board.

    Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
    Modified by Ru.Board
    © Ru.Board 2000-2020

    BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

    Рейтинг.ru