Обновления для Microsoft Windows 10 (IV) - [1689] :: Microsoft Windows

Код:

@echo off
echo DisableWU v2.0 from Harpy for you
echo disable AutoUpdate: DisableWU -a
echo disable WindowsUpdate: DisableWU -w
echo disable ReleaseUpgrade: DisableWU -r
echo disable all: DisableWU -awr
echo enable all: DisableWU -
echo.
set "vp=%~1"
if "%vp%" == "" goto :Eof
set "vKey=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"
set "vWowKey=HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows NT\CurrentVersion"
set "vWUPKey=HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate"
for /f "skip=2 tokens=3 delims= " %%i in ('reg query "%vKey%" /v "ReleaseId" /t REG_SZ 2^>nul') do if not defined ReleaseId set "ReleaseId=%%i"
for /f "skip=2 tokens=3 delims= " %%i in ('reg query "%vWowKey%" /v "ReleaseId" /t REG_SZ 2^>nul') do if not defined ReleaseId set "ReleaseId=%%i"
if not defined ReleaseId echo Current ReleaseId isn't detected&goto :Eof
rem set "ReleaseId=1809"
set "vNoAutoUpdate=1"
if /i "%vp:a=%" == "%vp%" set "vNoAutoUpdate=0"
reg add "%vWUPKey%\AU" /v "NoAutoUpdate" /t REG_DWORD /d "%vNoAutoUpdate%" /f
if /i "%vp:w=%" == "%vp%" (reg delete "%vWUPKey%" /v "DisableWindowsUpdateAccess" /f 2>nul) else (reg add "%vWUPKey%" /v "DisableWindowsUpdateAccess" /t REG_DWORD /d 1 /f)
if /i "%vp:r=%" == "%vp%" goto :End
reg add "%vWUPKey%" /v "TargetReleaseVersionInfo" /t REG_SZ /d "%ReleaseId%" /f
reg add "%vWUPKey%" /v "TargetReleaseVersion" /t REG_DWORD /d 1 /f
goto :Eof
:End
reg delete "%vWUPKey%" /v "TargetReleaseVersionInfo" /f 2>nul
reg delete "%vWUPKey%" /v "TargetReleaseVersion" /f 2>nul

Модерирует : KLASS, IFkO
KLASS (17-04-2022 09:07): Продолжение в Обновления для Microsoft Windows 10 (V)	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению