nsky
Newbie | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off
:: ~dtm.bat
:: Set Wd, Wn, Dt, Tm and Ms(Nt only) environment variables.
:: Sample:
:: call ~dtm
:: echo %wd%(%wn%), %dt% %tm%,%ms%
%1 %2
set t="%tmp%\~.bat"
set prmpt=%prompt%
if %OS%'==Windows_NT' goto winNT
:win9x
prompt %0 goto sub9x $d $t
command.com /e:2048 /c %0 goto sub0 >%t%
call %t%
goto finish
:winNT
prompt %~s0 goto subWD $d & command.com /e:2048 /c %~s0 goto sub0 >%t% & call %t%
set dt=%date%
for /f "tokens=1,2 delims=.," %%a in ("%time%") do (set tm=%%a& set ms=%%b)
:finish
if %wd%'==Пн' set wn=01
if %wd%'==Вт' set wn=02
if %wd%'==Ср' set wn=03
if %wd%'==Чт' set wn=04
if %wd%'==Пт' set wn=05
if %wd%'==Сб' set wn=06
if %wd%'==Вс' set wn=07
if %wd%'==Mon' set wn=01
if %wd%'==Tue' set wn=02
if %wd%'==Wed' set wn=03
if %wd%'==Thu' set wn=04
if %wd%'==Fri' set wn=05
if %wd%'==Sat' set wn=06
if %wd%'==Sun' set wn=07
del %t%
prompt %prmpt%
set prmpt=
set call=
set t=
:: debug
:: echo %wd%(%wn%), %dt% %tm%,%ms%
goto bye
:sub0
echo on
echo.
@echo off
goto bye
:sub9x
set wd=%3
set dt=%4
set tm=%5
goto bye
:subWD
set wd=%3
:bye
|
Всего записей: 5 | Зарегистр. 26-12-2005 | Отправлено: 16:20 06-05-2006 | Исправлено: nsky, 17:44 06-05-2006 |
|
