vbs logon скрипт для подключения сетевых дисков - [1] :: В помощь системному администратору

вот два скрипта, первый проверяет принадлежнойть юзера к опред. группе, второй мапит сетевые диски с обработкой ошибок и занесением инфы в EventLog. на их основе написать скрипт мапящий диски на основе групп думаю не так сложно

Код:

ON ERROR RESUME NEXT
Dim strUserDN, objSysInfo

set WshShell = CreateObject("WScript.Shell")
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objSysInfo = CreateObject("ADSystemInfo")

LogonServer=WshShell.ExpandEnvironmentStrings("%LogonServer%")
MsgBox "Logon server: " & LogonServer

strUserDN = objSysInfo.userName
MsgBox strUserDN

Set UserObj = GetObject("LDAP://" & strUserDN)

MsgBox "User '" & WshNetwork.username & "' connect to " & WshNetwork.computername

'Init Groups
Dim UserGroups
Dim GroupObj
UserGroups=""

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

MsgBox "Member of "& UserGroups

if InGroup("CN=Administrators") then
MsgBox "This user - Admin"
end if

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[" & strGroup & "]") Then
InGroup=True
End If
End Function

Код:

'==========================================================================
'
' VBScript Source File
'
' NAME: MapDrives.vbs
'
' AUTHOR: SergeyCVS
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================

Option Explicit
On Error Resume Next

Dim WshShell, WshNetwork

Set WshShell = WScript.CreateObject("WScript.Shell")

MapDrv "L:", "\\SRV\Users\" & WshShell.ExpandEnvironmentStrings("%USERNAME%")
MapDrv "R:", "\\SRV\Archive"
MapDrv "W:", "\\SRV\Work"
MapDrv "P:", "\\SRV\SUPPORT$"

'==========================================================================
'
' Function MapDrv(DrvLet, UNCPath)
'
' DrvLet - Буква устройства
' UNCPath - Сетевой путь
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================

Function MapDrv(DrvLet, UNCPath)

Dim WshNetwork ' Object variable
Dim Msg

Set WshNetwork = WScript.CreateObject("WScript.Network")

On Error Resume Next
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Select Case Err.Number
Case 0 ' No error

Case -2147023694
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case -2147024811
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case Else

Msg = "Mapping network drive error: " & _
CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _
"Error description: " & Err.Description & vbCrLf
Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf
Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf
Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf
Msg = Msg & "Device name: " & DrvLet & vbCrLf
Msg = Msg & "Map path: " & UNCPath

WshShell.LogEvent 1, Msg, "\\SRV"
End Select

End Function

----------
xxx: если цыплят зовут - цыпа, цыпа, цыпа
xxx: а утят - утя, утя, утя..
xxx: то пингвинов надо подзывать - пинг, пинг, пинг

Модерирует : lynx, Crash_Master, dg, emx, ShriEkeR
Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7