Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » В помощь системному администратору » таймер для .bat файла

Модерирует : lynx, Crash_Master, dg, emx, ShriEkeR

 Версия для печати • ПодписатьсяДобавить в закладки

Открыть новую тему     Написать ответ в эту тему

BigBear

Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
проблемма в следюющем
в связке w2k + terminal server + citrix  валится спулер печати (насмерть)
решение:
1. останавлтваем спулер (на всякий случай- он не всегда показывает что он остановлен)
    net stop spooler
2. очищаем папку спулера
    del /f /q C:\WINNT\system32\spool\*.*
3. стартуем спулер
    net start spooler
пишем соответствующий батник и в свойствах сервиса указываем что при ошибке запускать нужный файл
 
НО если между камандами нет паузы в 10-20 секунд - фокус не проходит
файлы заняты системой
 
А теперь вопрос -)?
 
как в камандной строке запустить таймер между командами

Всего записей: 276 | Зарегистр. 16-12-2001 | Отправлено: 08:39 25-03-2004
Akama

Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
напиши софтинку, на любом языке, да включай в батник. я так и сделал. могу поделиться, если нужно очень.

Всего записей: 333 | Зарегистр. 07-04-2002 | Отправлено: 08:43 25-03-2004
BigBear

Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Akama
Спасибо не откажусь!!
melex@mail.ru
P.S. с написанием проблеммы у меня -(((((
Еще раз спасибо

Всего записей: 276 | Зарегистр. 16-12-2001 | Отправлено: 08:50 25-03-2004
Cheery



.:МордератоР:.
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
BigBear

Цитата:
как в камандной строке запустить таймер между командами

например вставляя..
ping -n 5 localhost > nul  
5 секунд задержки..
либо такой код на vbs. файл называется 2Kwait.cmd

Код:
 
:: 2Kwait.cmd
@echo off
:: Wait %1 seconds
 
:: setup variables for the batch
setlocal
set vbscript=%temp%\~%~n0.vbs
set vbrun=cscript /NoLogo "%vbscript%"
 
 
::write script - only need be done once
:: watch %% for each %, ^& for &, ^| for |,  etc ...
>"%vbscript%" echo '  Temporary script for %0
>>"%vbscript%" echo WScript.Sleep Wscript.arguments(0) * 1000 - 200
 
 
:: Continue with script as normal, using "%vbrun%  seconds"  as often as you like to pause a number of seconds.
 
 
:: EXAMPLE assuming script is called as the wait command - %1 is number of seconds to wait  
:: One second is lopped off for overhead of writing the script the first time, and deleting it after done
::           although overhead is much less than that
:: default is 5 seconds
set /a zwait=%1 - 1  
if "%1"=="" set zwait=4
if %zwait% LSS 1 set zwait=1
:: Actual wait happens here
%vbrun%  %zwait%
 
 
:: uncomment next line to delete script when done  
del "%vbscript%"
 
:: Can be moved into path and given a reasonable name to run from any future batch or Windows program.  

запуск в виде CALL 2Kwait.cmd  10
можно сразу в виде vbs, но там есть неудобства..

----------
Away/DND

Всего записей: 52737 | Зарегистр. 04-04-2002 | Отправлено: 08:59 25-03-2004
BigBear

Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Cheery
 Сейчас буду пробовать
Спасибо
 
Добавлено
все вроде работает
буду ждать падение спулера (а это неизбежно)
там и посмотрим окончательно

Всего записей: 276 | Зарегистр. 16-12-2001 | Отправлено: 09:05 25-03-2004
ZevSforum

Advanced Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Ибо команда  
ping -n 5 localhost > nul  
лучше, сам у себя использую

Всего записей: 656 | Зарегистр. 11-09-2003 | Отправлено: 14:10 25-03-2004
nightlight

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
BigBear
Что-то не нндравятся мне длинные файлы сценариев...
Может как-нибудь попроще...
Например:
в Resourсe Kit  ( "Highly Recommended" )есть утилитка-> sleep n, где n -время в секундах.
 
Или накрайняк пишем такой mysleep.cmd файлик:
 
@echo off
echo WScript.sleep(%1); > %temp%\sleep.js
cscript //B %temp%\sleep.js
del /Q %temp%\sleep.js
 
Использование:
mysleep n
где n -время в миллисекундах.

Всего записей: 112 | Зарегистр. 17-03-2004 | Отправлено: 14:51 25-03-2004 | Исправлено: nightlight, 14:54 25-03-2004
Balancer

Newbie
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
perl -e "sleep N;"
 

Всего записей: 14 | Зарегистр. 19-03-2004 | Отправлено: 16:18 25-03-2004
BigBear

Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Все работает и самый простой вариант с пингами!!!! и с самописной прогой
тепер время подобрать осталось

Всего записей: 276 | Зарегистр. 16-12-2001 | Отправлено: 08:22 26-03-2004
Aleksanders



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
BigBear
По-моему, спулер - это системный сервис. В свойствах сервиса пощелкай закладки, там есть настройка восстановления сервиса. Если есть желание, можно записать туда батник, который запускался бы при падении сервиса, или просто тупо его рестартовать.

----------
LINUX = Linux Is Not a UniX

Всего записей: 1428 | Зарегистр. 07-07-2002 | Отправлено: 17:42 26-03-2004
Cheery



.:МордератоР:.
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Aleksanders

Цитата:
 В свойствах сервиса пощелкай закладки, там есть настройка восстановления сервиса. Если есть желание, можно записать туда батник, который запускался бы при падении сервиса, или просто тупо его рестартовать.

хм.. смотрим первый пост и ..

Цитата:
пишем соответствующий батник и в свойствах сервиса указываем что при ошибке запускать нужный файл  

иногда лучше молчать, чем говорить..

----------
Away/DND

Всего записей: 52737 | Зарегистр. 04-04-2002 | Отправлено: 01:50 27-03-2004
merlkerry

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Вариант с ping очень неплох , лучше чем VBScript -потому как память совсем не кушает.
И конечно выигрывает у ResKit SLEEP - потому как к примеру на 2000-й сервер, sleep нет в свободной загрузке, а значит для борцов за честное ПО не подходит .


----------
Вокруг одни враги.
Я испытываю естественный скептицизм по поводу чистоты человеческих намерений.

Всего записей: 1521 | Зарегистр. 16-09-2002 | Отправлено: 15:54 27-03-2004
sayanvd

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Недавно возникла необходимость вставить в .bat файл паузу на заданное число секунд, нашел в инете следующее решение без привлечения внешних программ.
 
"...вариант, который работает всегда и со всеми значениями от 1 до 999 секунд:
 
@Echo Off
 
SetLocal EnableExtensions EnableDelayedExpansion
 
If "%1"=="" Exit
If %1 LSS 0 GoTo :EOF
If %1 GTR 999 GoTo :EOF
 
Set pDelay=%1
Set iDelay=0
Set pTime=%Time:~7,1%
 
:WAIT
Set iTime=%Time:~7,1%
If %iTime% == %pTime% GoTo :WAIT
Set pTime=%iTime%
Set /a iDelay=%iDelay%+1
If %iDelay% LSS %pDelay% GoTo :WAIT
 
EndLocal
"

Всего записей: 165 | Зарегистр. 11-11-2005 | Отправлено: 12:37 10-04-2006
Открыть новую тему     Написать ответ в эту тему

Компьютерный форум Ru.Board » Компьютеры » В помощь системному администратору » таймер для .bat файла


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru